Good to Know Database

CANoe Konfiguration über VBScript öffnen und VT System aktivieren oder deaktivieren


Mit dem folgenden Visual Basic Script können Sie eine CANoe Konfiguration öffnen und zuvor festlegen ob Sie CANoe mit oder ohne VT System Unterstützung benutzen wollen. Nachdem Sie das VBScript mit einer CANoe Konfiguration als Argument aufgerufen haben, wird Ihnen eine Meldung angezeigt über welche Sie VT System aktivieren oder deaktivieren können. Je nachdem für welche Option Sie sich entschieden haben wird anschließend die CANoe Konfigurationsdatei angepasst und die übergebene CANoe Konfiguration mit CANoe geöffnet.

Option Explicit

' Declaration of variables
Dim strConfigurationFile
Dim intVTSystem
Dim objFileSystem
Dim strCanIniFile
Dim objApplication

' Check arguments
If WScript.Arguments.Count < 1 Then
  ' No arguments specified
  WScript.Echo "No CANoe configuration file specified." & vbCrLf & "Visual Basic Script has been aborted!"
  WScript.Quit()
Else
  ' Store specified CANoe configuration file name
  strConfigurationFile = WScript.Arguments(0)
End If

' Request user if VT System should be enabled
intVTSystem = MsgBox("Run CANoe with enabled VT System support?",4,"Select VT System support")

' Create object for filesystem access
Set objFileSystem = WScript.CreateObject("Scripting.FileSystemObject")

' Check path of CAN.ini
CheckCanIniPath()

' Enable or disable VT System support
VTSystemSupport()

' Deallocate filesystem object
Set objFileSystem = Nothing

' Launch CANoe
Set objApplication = WScript.CreateObject("CANoe.Application")

' Load the CANoe configuration
objApplication.Open strConfigurationFile

' Deallocate application object
Set objApplication = Nothing

' Quit Visual Basic Script
WScript.Quit()

' ====================================================================
' ===   Generic sub functions                                      ===
' ====================================================================

Sub CheckCanIniPath()
  ' Check path of CAN.ini
  If (objFileSystem.FileExists("C:\Documents and Settings\All Users\Application Data\Vector\CANoe\8.0\CAN.ini")) Then
    ' Windows XP SP3 EN
    strCanIniFile = "C:\Documents and Settings\All Users\Application Data\Vector\CANoe\8.0\CAN.ini"
  ElseIf (objFileSystem.FileExists("C:\Dokumente und Einstellungen\All Users\Anwendungsdaten\Vector\CANoe\8.0\CAN.ini")) Then
    ' Windows XP SP3 DE
    strCanIniFile = "C:\Dokumente und Einstellungen\All Users\Anwendungsdaten\Vector\CANoe\8.0\CAN.ini"
  ElseIf (objFileSystem.FileExists("C:\ProgramData\Vector\CANoe\8.0\CAN.ini")) Then
    ' Windows 7 SP1 EN
    strCanIniFile = "C:\ProgramData\Vector\CANoe\8.0\CAN.ini"
  Else
    strCanIniFile = ""
  End If
End Sub

Sub VTSystemSupport()
  ' Declaration of variables
  Dim objCanIniFile
  Dim strCanIniContent

  ' Enable or disable VT System support
  If Not strCanIniFile = "" Then
    ' Open CAN.ini for read access
    Set objCanIniFile = objFileSystem.OpenTextFile(strCanIniFile,1)

    ' Enable or disable VT System support in config file CANoe.ini
    If intVTSystem = 6 Then
      ' Enable VT System support
      strCanIniContent = Replace(objCanIniFile.ReadAll,"EnableVTS=0","EnableVTS=1")
    Else
      ' Disable VT System support
      strCanIniContent = Replace(objCanIniFile.ReadAll,"EnableVTS=1","EnableVTS=0")
    End If

    ' Open CAN.ini for writting
    Set objCanIniFile = objFileSystem.OpenTextFile(strCanIniFile,2)

    ' Write modified content
    objCanIniFile.Write(strCanIniContent)

    ' Close CAN.ini
    objCanIniFile.Close

    ' Deallocate CAN.ini object
    Set objCanIniFile = Nothing
  End If
End Sub


Dieser Eintrag wurde am 10.05.2013 erstellt.

Direkter Link zu dieser Seite: http://www.gtkdb.de/index_25_2217.html

[ Zur Startseite ]   [ Zur Kategorie ]


Valid XHTML 1.0 Transitional Valid CSS Valid Atom 1.0

© 2004-2018 by Georg Kainzbauer