Good to Know Database

XML-Testspezifikationen von CANoe ins HTML-Format konvertieren


Das folgende Visual Basic Script konvertiert die übergebenen XML-Testspezifikationen von CANoe in HTML-Testspezifikationen. Dies kann man auch über CANoe durchführen, jedoch muss man dazu erst das Testsetup laden. Indem man das VBScript im SendTo-Verzeichnis von Windows ablegt (bei Windows 7 unter %USERPROFILE%\AppData\Roaming\Microsoft\Windows\SendTo) kann man eine oder mehrere XML-Testspezifikationen direkt über den Menüpunkt Senden an im Kontextmenü konvertieren. Die erzeugten HTML-Testspezifikationen finden Sie im Anschluss im selben Verzeichnis wie die XML-Dateien.

Option Explicit

' Declaration of variables
Dim intArguments
Dim intCounter
Dim strWorkDir
Dim strCANoePath
Dim strXmlTestSpec
Dim strHtmlTestSpec
Dim objFileSystem
Dim objWScriptShell

' Get count of arguments
intArguments = WScript.Arguments.Count

' Check arguments
If intArguments < 1 Then
  ' No arguments specified
  WScript.Echo "No input file specified." & vbCrLf & "Visual Basic Script has been aborted!"
  WScript.Quit()
Else
  ' Create object for filesystem access
  Set objFileSystem = WScript.CreateObject("Scripting.FileSystemObject")

  ' Get current working directory
  strWorkDir = objFileSystem.GetAbsolutePathName(".")

  ' Check path of CANoe installation
  If (objFileSystem.FolderExists("C:\Program Files (x86)\Vector CANoe 8.5")) Then
    strCANoePath = "C:\Program Files (x86)\Vector CANoe 8.5"
  Else
    ' CANoe installation not found
    WScript.Echo "CANoe installation path not found." & vbCrLf & "Visual Basic Script has been aborted!"
    WScript.Quit()
  End If

  ' Deallocate filesystem object
  Set objFileSystem = Nothing

  ' Create WScript Shell object
  Set objWScriptShell = WScript.CreateObject("WScript.Shell")

  ' Check and transform each specified XML file
  For intCounter = 0 To (intArguments - 1)
    ' Store specified file name
    strXmlTestSpec = WScript.Arguments(intCounter)

    ' Check specified file name
    If InStr(strXmlTestSpec,".xml") <> 0 Then
      ' Create output file name
      strHtmlTestSpec = Replace(strXmlTestSpec,".xml",".html")

      ' Transform XML test spec
      objWScriptShell.Run """" & strCANoePath & "\Exec32\sabcmd.exe"" file:///""" & strCANoePath & "\Exec32\Report\testspec_onepage.xslt"" file:///""" & strXmlTestSpec & """ file:///""" & strHtmlTestSpec & """"
    Else
      ' No XML file specified
      WScript.Echo "Specified input file is no *.xml file." & vbCrLf & "File skipped!"
    End If
  Next

  ' Deallocate WScript Shell object
  Set objWScriptShell = Nothing
End If

' Quit Visual Basic Script
WScript.Quit()


Dieser Eintrag wurde am 29.03.2013 erstellt und zuletzt am 01.04.2018 bearbeitet.

Direkter Link zu dieser Seite: http://www.gtkdb.de/index_25_2164.html

[ Zur Startseite ]   [ Zur Kategorie ]


Valid XHTML 1.0 Transitional Valid CSS Valid Atom 1.0

© 2004-2018 by Georg Kainzbauer