Good to Know Database

CANoe 8.0: VT System mittels Batch-Skript aktivieren/deaktivieren


Sobald Sie in den CANoe 8.0 Einstellungen die Unterstützung für VT System aktivieren, wird der folgende Abschnitt zur Konfigurationsdatei CAN.ini hinzugefügt.

[VT_System]
EnableVTS=1

Wenn Sie Ihr Testsetup in verschiedenen Testumgebungen nutzen, welche möglicherweise nicht alle über ein VT System verfügen, müssen Sie gegebenenfalls die Unterstützung für VT System manuell über die Einstellungen wieder deaktivieren. Diesen Vorgang können Sie mit Hilfe des folgenden Batch-Skriptes automatisieren.

Nach dem Start des Skriptes können Sie auswählen ob der VT System Support aktiviert oder deaktiviert werden soll. Mittels der aktuell nicht genutzen Funktion TOGGLE_VTS kann der Wert der Option EnableVTS einfach gewechselt werden.

Hinweis: Änderungen an der Konfigurationsdatei CAN.ini sollten Sie nur vornehmen, wenn CANoe nicht gestartet ist. Beenden Sie deshalb vor dem Ausführen des Skriptes alle Instanzen von CANoe.

@echo off

setlocal DisableDelayedExpansion

rem Set original and temporary file
if exist "%ALLUSERSPROFILE%\Vector\CANoe\8.0\" (
  rem Windows 7 all users profile directory
  set "filename=%ALLUSERSPROFILE%\Vector\CANoe\8.0\CAN.ini"
  set "tempfile=%ALLUSERSPROFILE%\Vector\CANoe\8.0\CAN.ini.tmp"
) else if exist "%ALLUSERSPROFILE%\Application Data\Vector\CANoe\8.0\" (
  rem Windows XP all users profile directory
  set "filename=%ALLUSERSPROFILE%\Application Data\Vector\CANoe\8.0\CAN.ini"
  set "tempfile=%ALLUSERSPROFILE%\Application Data\Vector\CANoe\8.0\CAN.ini.tmp"
) else (
  call :ERROR "Configuration directory does not exist!"
  goto :EOF
)

rem Check if configuration file exist
if not exist "%filename%" (
  call :ERROR "Configuartion file %filename% does not exist!"
  goto :EOF
)

rem Request if VTS should be enabled or disabled
echo Enter "E" to enable or "D" to disable VTS:
set /p state=VTS state:

rem Check user input
if /i not "%state%"=="E" if /i not "%state%"=="D" (
  call :ERROR "Unknown state selected!"
  goto :EOF
)

rem Remove temorary file if exist
if exist "%tempfile%" del /f "%tempfile%"

rem Create empty temporary file
type nul > "%tempfile%"

rem Set line counter
set /a line=0

rem Parse each line of the input file
for /f "eol=$ tokens=* delims=" %%a in ('findstr /n $ "%filename%"') do (
  set string=%%a
  set /a line+=1
  setlocal EnableDelayedExpansion
  call :PROCEED
  >> "%tempfile%" echo.!string!
  endlocal
)

rem Delete original file
del /f "%filename%"

rem Move temporary file to original file location
move "%tempfile%" "%filename%" >nul

echo.
echo All Done.
goto :EOF

:PROCEED
if /i "%state%"=="E" (
  call :ENABLE_VTS
) else if /i "%state%"=="D" (
  call :DISABLE_VTS
) else (
  call :UNCHANGED_VTS
)
goto :EOF

:UNCHANGED_VTS
rem Change nothing
set string=!string:%line%:=!
goto :EOF

:ENABLE_VTS
rem Check if EnableVTS=0 and change to EnableVTS=1
set string=!string:%line%:=!
if "!string:~0,11!"=="EnableVTS=0" (
  set string=!string:0=1!
)
goto :EOF

:DISABLE_VTS
rem Check if EnableVTS=1 and change to EnableVTS=0
set string=!string:%line%:=!
if "!string:~0,11!"=="EnableVTS=1" (
  set string=!string:1=0!
)
goto :EOF

:TOGGLE_VTS
rem Check EnableVTS and change state
set string=!string:%line%:=!
if "!string:~0,11!"=="EnableVTS=0" (
  set string=!string:0=1!
) else if "!string:~0,11!"=="EnableVTS=1" (
  set string=!string:1=0!
)
goto :EOF

:ERROR
echo.
echo %~1
echo.
pause
goto :EOF


Dieser Eintrag wurde am 27.09.2012 erstellt.

Direkter Link zu dieser Seite: http://www.gtkdb.de/index_25_1873.html

[ Zur Startseite ]   [ Zur Kategorie ]


Valid XHTML 1.0 Transitional Valid CSS Valid Atom 1.0

© 2004-2018 by Georg Kainzbauer