Good to Know Database

Mehrsprachige Windows 7 Installations-DVD erstellen


Mit dem folgenden Skript können Sie mehrsprachige Windows 7 Installations-DVD's erstellen.

Voraussetzungen:
- Ein lauffähiges Windows 7 System auf welchem Sie die mehrsprachige Installations-DVD erstellen können.
- Eine Windows 7 Installations-DVD welche Sie in ein temporäres Verzeichnis auf dem Windows 7 System kopieren.
- Das Windows Automated Installation Kit (AIK) oder das Windows OEM Preinstallation Kit (OPK).
- Das entsprechende Multilingual User Interface (MUI) Language Pack welches Sie in die Installations-DVD implementieren wollen.

Wenn Sie auf einem Windows 7 System das AIK beziehungsweise OPK installiert haben, die komplette Windows Installations-DVD in ein temporäres Verzeichnis (zum Beispiel C:\Win7_DVD) kopiert wurde und sich das Language Pack ebenfalls auf dem System befindet (zum Beispiel C:\Win7_LP\de-de\lp.cab), können Sie das folgende Skript in eine *.cmd Datei kopieren und ausführen.

Hinweis: Sie können eine 64bit Installations-DVD auch auf einem 32bit System erstellen und eine 32bit Installations-DVD auch auf einem 64bit System.

@echo off

rem
rem Build Win7_MUI_DVD
rem
rem 20090803 v1.0    Build Win7_MUI_DVD from Windows 7 DVD and Language Pack
rem

set WORKDIR=%~dp0
set TEMPDIR=C:\Win7_TEMP
set MOUNTDIR=%TEMPDIR%\MOUNT
set LPEXTDIR=%TEMPDIR%\LPEXT
set KITPATH=
if exist "C:\Program Files\Windows AIK" set KITPATH=C:\Program Files\Windows AIK
if exist "C:\Program Files\Windows OPK" set KITPATH=C:\Program Files\Windows OPK
if "%KITPATH%"=="" goto E_KITPATH

:DVDPATH
echo.
echo Please enter the Windows 7 DVD directory (e.g.: C:\Win7_DVD) ...
echo.
set /p DVDPATH=
echo.
if exist "%DVDPATH%" goto LPPATH
echo.
echo The Windows 7 DVD directory "%DVDPATH%" does not exist! Try again.
echo.
goto DVDPATH

:LPPATH
echo.
echo Please enter the full path to MUI file (e.g.: C:\Win7_LP\de-de\lp.cab) ...
echo.
set /p LPPATH=
echo.
if exist "%LPPATH%" goto LANGUAGE
echo.
echo The MUI file "%LPPATH%" does not exist! Try again.
echo.
goto LPPATH

:LANGUAGE
echo.
echo Please enter the MUI ID (e.g.: de-de) ...
echo.
set /p LANGUAGE=
echo.

echo.
echo Please enter the Windows 7 Edition ID to modify (e.g.: 3) ...
echo.
echo x86  x64  Edition
echo  1    -   Windows 7 Starter
echo  2    1   Windows 7 Home Basic
echo  3    2   Windows 7 Home Premium
echo  4    3   Windows 7 Professional
echo  5    4   Windows 7 Ultimate
echo.
set /p EDITION=
echo.

:ISOPATH
echo.
echo Please enter the full path to ISO output file (e.g.: C:\Win7_MUI_DVD.iso) ...
echo.
set /p ISOPATH=
echo.
if not exist "%ISOPATH%" goto START
echo.
echo The file "%ISOPATH%" already exist! Try again.
echo.
goto ISOPATH

:START
if exist "%TEMPDIR%" rmdir /s /q "%TEMPDIR%"
if errorlevel 1 goto E_DELTMP

mkdir %TEMPDIR%
if errorlevel 1 goto E_MKDIR
mkdir %MOUNTDIR%
if errorlevel 1 goto E_MKDIR
mkdir %LPEXTDIR%
if errorlevel 1 goto E_MKDIR

"%KITPATH%\Tools\x86\Servicing\dism.exe" /Mount-Wim /WimFile:"%DVDPATH%\sources\install.wim" /Index:%EDITION% /MountDir:"%MOUNTDIR%"
if errorlevel 1 goto E_MOUNT

"%KITPATH%\Tools\x86\Servicing\dism.exe" /Image:"%MOUNTDIR%" /Add-Package /PackagePath:"%LPPATH%"
"%KITPATH%\Tools\x86\Servicing\dism.exe" /Image:"%MOUNTDIR%" /Gen-LangIni /Distribution:"%DVDPATH%"
"%KITPATH%\Tools\x86\Servicing\dism.exe" /Image:"%MOUNTDIR%" /Set-AllIntl:%LANGUAGE%
"%KITPATH%\Tools\x86\Servicing\dism.exe" /Image:"%MOUNTDIR%" /Set-TimeZone:"Central Europe Standard Time"
"%KITPATH%\Tools\x86\Servicing\dism.exe" /Image:"%MOUNTDIR%" /Set-SetupUILang:%LANGUAGE% /Distribution:"%DVDPATH%"
"%KITPATH%\Tools\x86\Servicing\dism.exe" /Image:"%MOUNTDIR%" /Gen-LangIni /Distribution:"%DVDPATH%"
"%KITPATH%\Tools\x86\Servicing\dism.exe" /Image:"%MOUNTDIR%" /Get-Packages /Format:Table
"%KITPATH%\Tools\x86\Servicing\dism.exe" /Image:"%MOUNTDIR%" /Get-Intl

"%KITPATH%\Tools\x86\Servicing\dism.exe" /Unmount-Wim /MountDir:"%MOUNTDIR%" /Commit
if errorlevel 1 goto E_UNMOUNT

expand "%LPPATH%" -f:* "%LPEXTDIR%"
xcopy "%LPEXTDIR%\setup\sources\%LANGUAGE%\*" "%DVDPATH%\sources\%LANGUAGE%" /cherkyi
xcopy "%LPEXTDIR%\sources\license\%LANGUAGE%\*" "%DVDPATH%\sources\license\%LANGUAGE%" /cherkyi

"%KITPATH%\Tools\x86\Servicing\dism.exe" /Mount-Wim /WimFile:"%DVDPATH%\sources\boot.wim" /Index:2 /MountDir:"%MOUNTDIR%"
if errorlevel 1 goto E_MOUNT

xcopy "%LPEXTDIR%\setup\sources\%LANGUAGE%\*" "%MOUNTDIR%\sources\%LANGUAGE%" /cherkyi
xcopy "%LPEXTDIR%\sources\license\%LANGUAGE%\*" "%MOUNTDIR%\sources\license\%LANGUAGE%" /cherkyi
copy "%DVDPATH%\sources\lang.ini" "%MOUNTDIR%\sources\lang.ini"

"%KITPATH%\Tools\x86\Servicing\dism.exe" /Unmount-Wim /MountDir:"%MOUNTDIR%" /Commit
if errorlevel 1 goto E_UNMOUNT

"%KITPATH%\Tools\x86\oscdimg.exe" -u1 -b"%DVDPATH%\boot\etfsboot.com" "%DVDPATH%" "%ISOPATH%"
if errorlevel 1 goto E_CREATEISO

if exist "%TEMPDIR%" rmdir /s /q "%TEMPDIR%"
if errorlevel 1 goto E_DELTMP

goto DONE

:E_KITPATH
set MESSAGE=Could not find the OPK/AIK folder!
goto END

:E_DELTMP
set MESSAGE=Could not delete temporary folder!
goto END

:E_MKDIR
set MESSAGE=Could not create temporary folder!
goto END

:E_MOUNT
set MESSAGE=Could not mount WIM image"!
goto END

:E_UNMOUNT
set MESSAGE=Could not unmount WIM image!
goto END

:E_CREATEISO
set MESSAGE=Could not create "%ISOPATH%"!
goto END

:DONE
cls
set MESSAGE=Done
goto END

:END
echo.
echo %MESSAGE%
echo.
pause
exit

Nachdem Sie das Skript aufgerufen haben, müssen Sie das Verzeichnis mit der Kopie der Installations-DVD, den Pfad zum Language Pack, die entsprechende Sprache, die vorhandene Windows Version und die ISO-Ausgabedatei angeben. Danach erstellt das Skript automatisch ein neues ISO-Image welches Sie anschließend brennen und zur Installation verwenden können.

Hinweis: Beachten Sie bitte die abweichende Nummerierung der Editionen zwischen 32bit und 64bit. Da es keine 64bit Version von Windows 7 Starter gibt, beginnt hier die Nummerierung bei Home Basic.

Wenn Sie die Installation von der somit erstellten mehrsprachigen Installations-DVD starten, können Sie im ersten Auswahlfenster die Sprache der Installations-Oberfläche auswählen und im zweiten Dialog die Sprache welche installiert werden soll.

Weiterführende Tutorials

Windows 7 Multilingual User Interface Packs herunterladen
Windows 7 Multilingual User Interface Pack entpacken
Windows 7 x86 Installations-DVD mit integriertem SP1 erstellen
Windows 7 x64 Installations-DVD mit integriertem SP1 erstellen
Windows 7 SP1 Installations-DVD mit einer zusätzlichen Sprache ausstatten
Windows 7 SP1 Installations-DVD mit mehreren zusätzlichen Sprachen ausstatten
Windows 7 Installations-DVD mit Versionsauswahl erstellen oder Standardversion ändern


Dieser Eintrag wurde am 05.08.2009 erstellt und zuletzt am 24.01.2016 bearbeitet.

Direkter Link zu dieser Seite: http://www.gtkdb.de/index_17_717.html

[ Zur Startseite ]   [ Zur Kategorie ]


Valid XHTML 1.0 Transitional Valid CSS Valid Atom 1.0

© 2004-2018 by Georg Kainzbauer