Good to Know Database

Windows 7 SP1 Installations-DVD mit einer zusätzlichen Sprache ausstatten


Standardmäßig bringt eine Windows 7 Installations-DVD nur eine Sprache mit. Wenn Sie Windows 7 in einer anderen Sprache benötigen, müssen Sie im Nachhinein ein Multilingual User Interface Pack installieren oder eine Installations-DVD in der gewünschten Sprache verwenden. Die Installation eines Multilingual User Interface Packs wird von Microsoft allerdings nur bei Windows 7 Ultimate und Windows 7 Enterprise unterstützt. Die folgende Anleitung soll Ihnen zeigen, wie Sie eine Windows 7 SP1 Installations-DVD um eine weitere Sprache erweitern. Dazu werden die bereits erwähnten Multilingual User Interface Packs verwendet, welche sich auf diese Weise auch für Windows 7 Starter (nur bei 32-bit verfügbar), Home Basic, Home Premium und Professional verwenden lassen.

Voraussetzungen:
- Eine Windows 7 SP1 x86 oder x64 Installations-DVD.
- Ein lauffähiges Windows 7 SP1 x86 beziehungsweise x64 System mit 15GB freien Speicherplatz.
- Auf dem System muss das Windows Automated Installation Kit (AIK) installiert sein.
- Im selben Verzeichnis wie dieses Batch-Skript muss sich das entsprechende Multilingual User Interface Pack für Windows 7 SP1 befinden.

Eine Liste mit Download-Links der einzelnen Language Packs für Windows 7 SP1 finden Sie auf der Seite Windows 7 SP1 Multilingual User Interface Packs herunterladen.

Hinweis: Beachten Sie bitte, dass Sie ein Multilingual User Interface Pack nur unter der Architektur entpacken können, für welche es auch bestimmt ist. Das bedeutet, Sie können das folgende Batch-Skript bei einem 32-bit Language Pack nur auf einem 32-bit System und bei einem 64-bit Language Pack nur auf einem 64-bit System einsetzen.

Nachdem Sie alle Voraussetzungen erfüllt haben, müssen Sie im Batch-Skript die Variablen DVDDRIVE, WIN7ARCH, WIN7DVDDIR, WIN7DVDISO und TEMPDIR an Ihre Anforderungen anpassen. Danach führen Sie das Batch-Skript als Administrator aus.

@echo off

rem
rem Create multilingual Windows 7 x86/x64 SP1 DVD
rem
rem 20120324 v1.0    Create multilingual Windows 7 x86/x64 SP1 DVD
rem

rem Current working directory where also the language pack executables are located
rem Please don't touch!
set WORKDIR=%~dp0

rem Drive letter of your DVD drive (e.g. "F:")
set DVDDRIVE=F:

rem Architecture of the Windows 7 SP1 DVD
rem Set "x86" for 32 bit architecture
rem Set "amd64" for 64 bit architecture
set WIN7ARCH=amd64

rem Temporary directory to store the Windows 7 DVD content (e.g. "D:\Win7_SP1_DVD")
set WIN7DVDDIR=D:\Win7_SP1_%WIN7ARCH%_DVD

rem Path and filename for the ISO output file (e.g. "D:\Win7_SP1_MUI_DVD.iso")
set WIN7DVDISO=D:\Win7_SP1_%WIN7ARCH%_MUI_DVD.iso

rem File name of the language pack executable without the file extension (e.g. "windows6.1-kb2483139-x64-en-us_9b9c8a867baff2920507fbf1e1b4a158572b9b87")
set LPFILENAME=windows6.1-kb2483139-x64-en-us_9b9c8a867baff2920507fbf1e1b4a158572b9b87

rem Language of the language pack (e.g. "de-de" or "en-us")
set LANGUAGE=en-us

rem Some temporary working directories
set TEMPDIR=D:\Win7_SP1_%WIN7ARCH%_MUI
set EXTRACTDIR=%TEMPDIR%\extract
set MOUNTDIR=%TEMPDIR%\mount

rem Path to the Windows AIK or Windows OPK
set KITPATH=
if exist "C:\Program Files\Windows AIK" set KITPATH=C:\Program Files\Windows AIK
if exist "C:\Program Files\Windows OPK" set KITPATH=C:\Program Files\Windows OPK
if "%KITPATH%"=="" goto E_KITPATH

rem ###################################################################
rem # NORMALLY THERE IS NO NEED TO CHANGE ANYTHING BELOW THIS COMMENT #
rem ###################################################################

echo.
echo Remove temporary directories if they already exist
echo.
if exist "%WIN7DVDDIR%" rmdir /s /q "%WIN7DVDDIR%"
if errorlevel 1 goto E_DELDIR
if exist "%TEMPDIR%" rmdir /s /q "%TEMPDIR%"
if errorlevel 1 goto E_DELDIR

echo.
echo Create temporary directories
echo.
mkdir "%WIN7DVDDIR%"
if errorlevel 1 goto E_MKDIR
mkdir "%TEMPDIR%"
if errorlevel 1 goto E_MKDIR
mkdir "%EXTRACTDIR%"
if errorlevel 1 goto E_MKDIR
mkdir "%MOUNTDIR%"
if errorlevel 1 goto E_MKDIR

echo.
echo Copy Windows 7 SP1 DVD to the temporary directory
echo.
echo Please insert the Windows 7 SP1 %WIN7ARCH% DVD into the DVD drive %DVDDRIVE%
echo.
pause
xcopy %DVDDRIVE%\*.* /E /F "%WIN7DVDDIR%"

echo.
echo Extract language pack executable
echo.
if not exist "%WORKDIR%\%LPFILENAME%.exe" goto E_LPFILE
start %WORKDIR%\%LPFILENAME%.exe

:WAIT
rem Wait if lp.cab doesn't exist
if not exist lp.cab goto WAIT

:RETRY
rem Rename lp.cab after extraction has finished
rename lp.cab %LPFILENAME%.cab
if exist lp.cab goto RETRY

echo.
echo Move extracted language pack to %TEMPDIR%
echo.
move %LPFILENAME%.cab "%TEMPDIR%\%LPFILENAME%.cab"

rem Set count of available Windows 7 versions
if "%WIN7ARCH%"=="x86"   set VERSIONS=5
if "%WIN7ARCH%"=="amd64" set VERSIONS=4

rem Add language pack files to the installation images
for /L %%i in (1, 1, %VERSIONS%) do (
  echo.
  echo Add language pack files to the installation image %%i of %VERSIONS%
  echo.
  "%KITPATH%\Tools\x86\Servicing\Dism.exe" /Mount-Wim /Wimfile:"%WIN7DVDDIR%\sources\install.wim" /Index:%%i /MountDir:"%MOUNTDIR%"
  if errorlevel 1 goto E_MOUNT
  "%KITPATH%\Tools\x86\Servicing\Dism.exe" /Image:"%MOUNTDIR%" /Add-Package /PackagePath:"%TEMPDIR%\%LPFILENAME%.cab"
  "%KITPATH%\Tools\x86\Servicing\Dism.exe" /Image:"%MOUNTDIR%" /Gen-LangIni /Distribution:"%WIN7DVDDIR%"
  "%KITPATH%\Tools\x86\Servicing\Dism.exe" /Image:"%MOUNTDIR%" /Set-AllIntl:%LANGUAGE%
  "%KITPATH%\Tools\x86\Servicing\Dism.exe" /Image:"%MOUNTDIR%" /Set-TimeZone:"Central Europe Standard Time"
  "%KITPATH%\Tools\x86\Servicing\Dism.exe" /Image:"%MOUNTDIR%" /Set-SetupUILang:%LANGUAGE% /Distribution:"%WIN7DVDDIR%"
  "%KITPATH%\Tools\x86\Servicing\Dism.exe" /Image:"%MOUNTDIR%" /Gen-LangIni /Distribution:"%WIN7DVDDIR%"
  "%KITPATH%\Tools\x86\Servicing\Dism.exe" /Image:"%MOUNTDIR%" /Get-Packages /Format:Table
  "%KITPATH%\Tools\x86\Servicing\Dism.exe" /Image:"%MOUNTDIR%" /Get-Intl
  "%KITPATH%\Tools\x86\Servicing\Dism.exe" /Unmount-Wim /MountDir:"%MOUNTDIR%" /Commit
  if errorlevel 1 goto E_UNMOUNT
)

echo.
echo Add language pack files to the Windows 7 SP1 DVD
echo.
expand "%TEMPDIR%\%LPFILENAME%.cab" -F:* "%EXTRACTDIR%"
xcopy "%EXTRACTDIR%\setup\sources\%LANGUAGE%\*" "%WIN7DVDDIR%\sources\%LANGUAGE%" /cherkyi
xcopy "%EXTRACTDIR%\sources\license\%LANGUAGE%\*" "%WIN7DVDDIR%\sources\license\%LANGUAGE%" /cherkyi

echo.
echo Add language pack files to the boot image
echo.
"%KITPATH%\Tools\x86\Servicing\Dism.exe" /Mount-Wim /WimFile:"%WIN7DVDDIR%\sources\boot.wim" /Index:2 /MountDir:"%MOUNTDIR%"
if errorlevel 1 goto E_MOUNT
xcopy "%EXTRACTDIR%\setup\sources\%LANGUAGE%\*" "%MOUNTDIR%\sources\%LANGUAGE%" /cherkyi
xcopy "%EXTRACTDIR%\sources\license\%LANGUAGE%\*" "%MOUNTDIR%\sources\license\%LANGUAGE%" /cherkyi
copy "%WIN7DVDDIR%\sources\lang.ini" "%MOUNTDIR%\sources\lang.ini"
"%KITPATH%\Tools\x86\Servicing\Dism.exe" /Unmount-Wim /MountDir:"%MOUNTDIR%" /Commit
if errorlevel 1 goto E_UNMOUNT

echo.
echo Create Windows 7 SP1 %WIN7ARCH% MUI ISO image
echo.
"%KITPATH%\Tools\x86\oscdimg.exe" -u1 -b"%WIN7DVDDIR%\boot\etfsboot.com" "%WIN7DVDDIR%" "%WIN7DVDISO%"
if errorlevel 1 goto E_CREATEISO

echo.
echo Remove temporary directories
echo.
if exist "%WIN7DVDDIR%" rmdir /s /q "%WIN7DVDDIR%"
if errorlevel 1 goto E_DELDIR
if exist "%TEMPDIR%" rmdir /s /q "%TEMPDIR%"
if errorlevel 1 goto E_DELDIR

goto DONE

:E_KITPATH
set MESSAGE=Could not find the AIK/OPK directory!
goto END

:E_DELDIR
set MESSAGE=Could not delete temporary directory!
goto END

:E_MKDIR
set MESSAGE=Could not create temporary directory!
goto END

:E_LPFILE
set MESSAGE=Could not find language pack executable!
goto END

:E_MOUNT
set MESSAGE=Could not mount WIM image!
goto END

:E_UNMOUNT
set MESSAGE=Could not unmount WIM image!
goto END

:E_CREATEISO
set MESSAGE=Could not create "%WIN7DVDISO%"!
goto END

:DONE
cls
set MESSAGE=Done
goto END

:END
echo.
echo %MESSAGE%
echo.
pause
exit

Weiterführende Tutorials

Windows 7 Multilingual User Interface Pack entpacken
Windows 7 SP1 Installations-DVD mit mehreren zusätzlichen Sprachen ausstatten
Windows 7 Installations-DVD mit Versionsauswahl erstellen oder Standardversion ändern


Dieser Eintrag wurde am 24.03.2012 erstellt und zuletzt am 24.01.2016 bearbeitet.

Direkter Link zu dieser Seite: http://www.gtkdb.de/index_17_1540.html

[ Zur Startseite ]   [ Zur Kategorie ]


Valid XHTML 1.0 Transitional Valid CSS Valid Atom 1.0

© 2004-2018 by Georg Kainzbauer