Good to Know Database

Windows 7 Multilingual User Interface Pack entpacken


Wenn Sie versuchen ein Windows 7 Multilingual User Interface Pack (auch Language Pack genannt) zum Beispiel unter Windows 7 Home Premium zu entpacken, wird die enthaltene Datei lp.cab zwar extrahiert aber im Anschluss automatisch wieder gelöscht. Das liegt daran, dass die Windows 7 MUI Packs ausschließlich für Windows 7 Ultimate und Windows 7 Enterprise bestimmt sind. Durch das folgende Batch-Skript können Sie jedoch mit einem kleinen Trick die Language Packs auch unter einer anderen Windows 7 Version entpacken.

Eine Liste mit Download-Links der einzelnen Language Packs für Windows 7 SP1 finden Sie auf der Seite Windows 7 SP1 Multilingual User Interface Packs herunterladen. Die Download-Links für Windows 7 RTM sind auf der Seite Windows 7 Multilingual User Interface Packs herunterladen gelistet. Das zu extrahierende Multilingual User Interface Pack muss nach dem Download im selben Verzeichnis abgelegt werden, in welchem sich auch das folgende Batch-Skript befindet.

Hinweis: Beachten Sie bitte, dass Sie ein Multilingual User Interface Pack nur unter der Architektur entpacken können, für welche es auch bestimmt ist. Das bedeutet, Sie können ein 32-bit Language Pack nur auf einem 32-bit System und ein 64-bit Language Pack nur auf einem 64-bit System entpacken.

Bevor Sie das folgende Batch-Skript verwenden, sollten Sie die Variablen INPUT und OUTPUT entsprechend dem gewünschten Multilingual User Interface Pack anpassen.

@echo off

rem
rem Extract Windows 7 x86/x64 language pack
rem
rem 20120324 v1.0    Extract Windows 7 x86/x64 language pack
rem

rem Current working directory where also the language pack executable is located
rem Please don't touch!
set WORKDIR=%~dp0

rem Filename of the language pack executable (e.g. "windows6.1-kb2483139-x64-en-us_9b9c8a867baff2920507fbf1e1b4a158572b9b87.exe")
set INPUT=windows6.1-kb2483139-x64-en-us_9b9c8a867baff2920507fbf1e1b4a158572b9b87.exe

rem Filename of the extracted language pack (e.g. "windows6.1-kb2483139-x64-en-us_9b9c8a867baff2920507fbf1e1b4a158572b9b87.cab")
set OUTPUT=windows6.1-kb2483139-x64-en-us_9b9c8a867baff2920507fbf1e1b4a158572b9b87.cab

rem ###################################################################
rem # NORMALLY THERE IS NO NEED TO CHANGE ANYTHING BELOW THIS COMMENT #
rem ###################################################################

echo.
echo Extract language pack executable
echo.
if not exist "%WORKDIR%\%INPUT%" goto E_LPFILE
start %WORKDIR%\%INPUT%

:WAIT
rem Wait if lp.cab doesn't exist
if not exist lp.cab goto WAIT

:RETRY
rem Rename lp.cab after extraction has finished
rename lp.cab %OUTPUT%
if exist lp.cab goto RETRY

echo.
echo Move extracted language pack to %WORKDIR%
echo.
move %OUTPUT% "%WORKDIR%\%OUTPUT%"

goto DONE

:E_LPFILE
set MESSAGE=Could not find language pack executable!
goto END

:DONE
cls
set MESSAGE=Done
goto END

:END
echo.
echo %MESSAGE%
echo.
pause
exit


Dieser Eintrag wurde am 24.03.2012 erstellt und zuletzt am 24.01.2016 bearbeitet.

Direkter Link zu dieser Seite: http://www.gtkdb.de/index_17_1539.html

[ Zur Startseite ]   [ Zur Kategorie ]


Valid XHTML 1.0 Transitional Valid CSS Valid Atom 1.0

© 2004-2018 by Georg Kainzbauer