Good to Know Database

Windows 7 SP1 Installations-DVD mit Versionsauswahl automatisch erstellen


Das folgende Batch-Skript ist eine Zusammenfassung der in den Anleitungen Windows 7 x86 Installations-DVD mit integriertem SP1 erstellen, Windows 7 x64 Installations-DVD mit integriertem SP1 erstellen und Windows 7 Installations-DVD mit Versionsauswahl erstellen oder Standardversion ändern beschriebenen Vorgehensweise.

Sie können mit diesem Batch-Skript eine 32- oder 64-bit Windows 7 RTM Installations-DVD um das Service Pack 1 erweiteren und die Installation aller Windows 7 Versionen (Starter (nur bei 32-bit), Home Basic, Home Premium, Professional und Ultimate) freischalten.

Voraussetzungen:
- Eine Windows 7 x86 oder x64 Installations-DVD.
- Ein lauffähiges Windows 7 x86 beziehungsweise x64 System mit 20GB freien Speicherplatz.
- Auf dem System muss das Windows Automated Installation Kit (AIK) installiert sein.
- Im selben Verzeichnis wie dieses Batch-Skript muss sich die entsprechende Version des Windows 7 Service Packs 1 befinden.

Hinweis: Sie können eine 32-bit Installations-DVD von Windows 7 auch unter einem 64-bit Windows 7 System modifizieren.

Nachdem Sie alle Voraussetzungen erfüllt haben, müssen Sie im Batch-Skript die Variablen DVDDRIVE, WIN7ARCH, WIN7DVDDIR, WIN7DVDISO und SLIPSTREAMDIR an Ihre Anforderungen anpassen. Danach führen Sie das Batch-Skript als Administrator aus.

Nachdem die notwendigen Dateien aus dem jeweiligen Service Pack entpackt wurden, müssen drei Dateien manuell bearbeitet werden. Diese Dateien werden automatisch im Notepad nacheinander geöffnet. Welche Änderungen Sie darin vornehmen müssen können Sie in der Anleitung Windows 7 x86 Installations-DVD mit integriertem SP1 erstellen beziehungsweise Windows 7 x64 Installations-DVD mit integriertem SP1 erstellen nachlesen.

@echo off

rem
rem Create Windows 7 x86/x64 SP1 DVD with all versions enabled
rem
rem 20120324 v1.0    Create Windows 7 x86/x64 SP1 DVD with all versions enabled
rem

rem Current working directory where also the SP1 executable is located
rem Please don't touch!
set WORKDIR=%~dp0

rem Drive letter of your DVD drive (e.g. "F:")
set DVDDRIVE=F:

rem Architecture of the Windows 7 DVD
rem Set "x86" for 32 bit architecture
rem Set "amd64" for 64 bit architecture
set WIN7ARCH=amd64

rem Temporary directory to store the Windows 7 DVD content (e.g. "D:\Win7_DVD")
set WIN7DVDDIR=D:\Win7_%WIN7ARCH%_DVD

rem Path and filename for the ISO output file (e.g. "D:\Win7_SP1_DVD.iso")
set WIN7DVDISO=D:\Win7_SP1_%WIN7ARCH%_DVD.iso

rem File name of the SP1 executable without the file extension
rem Set "windows6.1-KB976932-X86" for 32 bit architecture
rem Set "windows6.1-KB976932-X64" for 64 bit architecture
set SP1FILENAME=
if "%WIN7ARCH%"=="x86"   set SP1FILENAME=windows6.1-KB976932-X86
if "%WIN7ARCH%"=="amd64" set SP1FILENAME=windows6.1-KB976932-X64
if "%SP1FILENAME%"=="" goto E_WIN7ARCH

rem Some temporary working directories
set SLIPSTREAMDIR=D:\Win7_%WIN7ARCH%_Slipstream
set EXTRACTDIR=%SLIPSTREAMDIR%\extract
set MOUNTDIR=%SLIPSTREAMDIR%\mount
set TEMPDIR=%SLIPSTREAMDIR%\temp

rem Path to the Windows AIK or Windows OPK
set KITPATH=
if exist "C:\Program Files\Windows AIK" set KITPATH=C:\Program Files\Windows AIK
if exist "C:\Program Files\Windows OPK" set KITPATH=C:\Program Files\Windows OPK
if "%KITPATH%"=="" goto E_KITPATH

rem ###################################################################
rem # NORMALLY THERE IS NO NEED TO CHANGE ANYTHING BELOW THIS COMMENT #
rem ###################################################################

echo.
echo Remove temporary directories if they already exist
echo.
if exist "%WIN7DVDDIR%" rmdir /s /q "%WIN7DVDDIR%"
if errorlevel 1 goto E_DELDIR
if exist "%SLIPSTREAMDIR%" rmdir /s /q "%SLIPSTREAMDIR%"
if errorlevel 1 goto E_DELDIR

echo.
echo Create temporary directories
echo.
mkdir "%WIN7DVDDIR%"
if errorlevel 1 goto E_MKDIR
mkdir "%SLIPSTREAMDIR%"
if errorlevel 1 goto E_MKDIR
mkdir "%EXTRACTDIR%"
if errorlevel 1 goto E_MKDIR
mkdir "%MOUNTDIR%"
if errorlevel 1 goto E_MKDIR
mkdir "%TEMPDIR%"
if errorlevel 1 goto E_MKDIR

echo.
echo Copy Windows 7 DVD to the temporary directory
echo.
echo Please insert the Windows 7 %WIN7ARCH% DVD into the DVD drive %DVDDRIVE%
echo.
pause
xcopy %DVDDRIVE%\*.* /E /F "%WIN7DVDDIR%"

echo.
echo Extract Windows 7 SP1 executable
echo.
if not exist "%WORKDIR%\%SP1FILENAME%.exe" goto E_SP1FILE
"%WORKDIR%\%SP1FILENAME%.exe" /X:"%TEMPDIR%"
echo.
echo Please wait a while before continue!
echo.
pause

echo.
echo Extract required files
echo.
copy "%TEMPDIR%\%SP1FILENAME%.cab" "%EXTRACTDIR%"
expand "%EXTRACTDIR%\%SP1FILENAME%.cab" -F:* "%EXTRACTDIR%"
expand "%EXTRACTDIR%\NestedMPPContent.cab" -F:* "%EXTRACTDIR%"
expand "%EXTRACTDIR%\KB976933-LangsCab*.cab" -F:* "%EXTRACTDIR%"

echo.
echo Open the configuration files for manual editing
echo.
notepad "%EXTRACTDIR%\Windows7SP1-KB976933~31bf3856ad364e35~%WIN7ARCH%~~6.1.1.17514.mum"
notepad "%EXTRACTDIR%\update.mum"
notepad "%EXTRACTDIR%\update.ses"

rem Set count of available Windows 7 versions
if "%WIN7ARCH%"=="x86"   set VERSIONS=5
if "%WIN7ARCH%"=="amd64" set VERSIONS=4

rem Add SP1 files to the installation images
for /L %%i in (1, 1, %VERSIONS%) do (
  echo.
  echo Add SP1 files to the installation image %%i of %VERSIONS%
  echo.
  "%KITPATH%\Tools\x86\Servicing\dism.exe" /Mount-Wim /Wimfile:"%WIN7DVDDIR%\sources\install.wim" /Index:%%i /MountDir:"%MOUNTDIR%"
  if errorlevel 1 goto E_MOUNT
  "%KITPATH%\Tools\x86\Servicing\dism.exe" /Image:"%MOUNTDIR%" /Add-Package /PackagePath:"%EXTRACTDIR%"
  "%KITPATH%\Tools\x86\Servicing\dism.exe" /Unmount-Wim /MountDir:"%MOUNTDIR%" /Commit
  if errorlevel 1 goto E_UNMOUNT
)

echo.
echo Remove ei.cfg from sources directory
echo.
if exist "%WIN7DVDDIR%\sources\ei.cfg" del "%WIN7DVDDIR%\sources\ei.cfg"

echo.
echo Create Windows 7 %WIN7ARCH% SP1 ISO image
echo.
"%KITPATH%\Tools\x86\oscdimg.exe" -u1 -b"%WIN7DVDDIR%\boot\etfsboot.com" "%WIN7DVDDIR%" "%WIN7DVDISO%"
if errorlevel 1 goto E_CREATEISO

echo.
echo Remove temporary directories
echo.
if exist "%WIN7DVDDIR%" rmdir /s /q "%WIN7DVDDIR%"
if errorlevel 1 goto E_DELDIR
if exist "%SLIPSTREAMDIR%" rmdir /s /q "%SLIPSTREAMDIR%"
if errorlevel 1 goto E_DELDIR

goto DONE

:E_WIN7ARCH
set MESSAGE=Please check the Windows 7 architecture!
goto END

:E_KITPATH
set MESSAGE=Could not find the AIK/OPK directory!
goto END

:E_DELDIR
set MESSAGE=Could not delete temporary directory!
goto END

:E_MKDIR
set MESSAGE=Could not create temporary directory!
goto END

:E_SP1FILE
set MESSAGE=Could not find SP1 executable!
goto END

:E_MOUNT
set MESSAGE=Could not mount WIM image!
goto END

:E_UNMOUNT
set MESSAGE=Could not unmount WIM image!
goto END

:E_CREATEISO
set MESSAGE=Could not create "%WIN7DVDISO%"!
goto END

:DONE
cls
set MESSAGE=Done
goto END

:END
echo.
echo %MESSAGE%
echo.
pause
exit


Dieser Eintrag wurde am 24.03.2012 erstellt und zuletzt am 24.01.2016 bearbeitet.

Direkter Link zu dieser Seite: http://www.gtkdb.de/index_17_1537.html

[ Zur Startseite ]   [ Zur Kategorie ]


Valid XHTML 1.0 Transitional Valid CSS Valid Atom 1.0

© 2004-2018 by Georg Kainzbauer