Good to Know Database

Windows Server 2008 R2 SP1 Installations-DVD mit einer zusätzlichen Sprachen ausstatten


Standardmäßig bringt eine Windows Server 2008 R2 Installations-DVD nur eine Sprache mit. Wenn Sie Windows Server 2008 R2 in einer anderen Sprache benötigen, müssen Sie im Nachhinein ein Multilingual User Interface Pack installieren oder eine Installations-DVD in der gewünschten Sprache verwenden. Die folgende Anleitung soll Ihnen zeigen, wie Sie eine Windows Server 2008 R2 SP1 Installations-DVD um eine weitere Sprache erweitern. Dazu werden die bereits erwähnten Multilingual User Interface Packs verwendet.

Voraussetzungen:
- Eine Windows Server 2008 R2 SP1 x64 Installations-DVD.
- Ein lauffähiges Windows 7 x64 oder ein Windows Server 2008 R2 x64 System mit 15GB freien Speicherplatz.
- Auf dem System muss das Windows Automated Installation Kit (AIK) installiert sein.
- Im selben Verzeichnis wie dieses Batch-Skript muss sich das entsprechende Multilingual User Interface Pack für Windows Server 2008 R2 SP1 befinden.

Hinweis: Sollten Sie keine Windows Server 2008 R2 SP1 x64 Installations-DVD zur Hand haben, können Sie sich auch die kostenlose Windows Server 2008 R2 SP1 Evaluation Version von der Microsoft-Webseite herunterladen.

Ein ISO-Image mit den benötigten Windows Server 2008 R2 SP1 Multilingual User Interface Packs kann ebenfalls kostenlos von der Microsoft-Webseite heruntergeladen werden.

Nachdem Sie alle Voraussetzungen erfüllt haben, müssen Sie im Batch-Skript die Variablen DVDDRIVE, WINSRVDVDDIR, WINSRVDVDISO und TEMPDIR an Ihre Anforderungen anpassen. Danach führen Sie das Batch-Skript als Administrator aus.

@echo off

rem
rem Create multilingual Windows Server 2008 R2 SP1 x64 DVD
rem
rem 20120408 v1.0    Create multilingual Windows Server 2008 R2 SP1 x64 DVD
rem

rem Current working directory where also the language packs are located
rem Please don't touch!
set WORKDIR=%~dp0

rem Drive letter of your DVD drive (e.g. "F:")
set DVDDRIVE=F:

rem Architecture of the Windows Server 2008 R2 SP1 DVD
rem Set "amd64" for 64 bit architecture
set WINSRVARCH=amd64

rem Temporary directory to store the Windows Server 2008 R2 SP1 DVD content (e.g. "D:\Win2k8R2_SP1_DVD")
set WINSRVDVDDIR=D:\WinSrv2k8R2_SP1_%WINSRVARCH%_DVD

rem Path and filename for the ISO output file (e.g. "D:\WinSrv2k8R2_SP1_MUI_DVD.iso")
set WINSRVDVDISO=D:\WinSrv2k8R2_SP1_%WINSRVARCH%_MUI_DVD.iso

rem File name of the language pack (e.g. "lp.cab")
set LPFILENAME=lp.cab

rem Language of the language pack (e.g. "de-de" or "en-us")
set LANGUAGE=en-us

rem Some temporary working directories
set TEMPDIR=D:\WinSrv2k8R2_SP1_%WINSRVARCH%_MUI
set EXTRACTDIR=%TEMPDIR%\extract
set MOUNTDIR=%TEMPDIR%\mount

rem Path to the Windows AIK or Windows OPK
set KITPATH=
if exist "C:\Program Files\Windows AIK" set KITPATH=C:\Program Files\Windows AIK
if exist "C:\Program Files\Windows OPK" set KITPATH=C:\Program Files\Windows OPK
if "%KITPATH%"=="" goto E_KITPATH

rem ###################################################################
rem # NORMALLY THERE IS NO NEED TO CHANGE ANYTHING BELOW THIS COMMENT #
rem ###################################################################

echo.
echo Remove temporary directories if they already exist
echo.
if exist "%WINSRVDVDDIR%" rmdir /s /q "%WINSRVDVDDIR%"
if errorlevel 1 goto E_DELDIR
if exist "%TEMPDIR%" rmdir /s /q "%TEMPDIR%"
if errorlevel 1 goto E_DELDIR

echo.
echo Create temporary directories
echo.
mkdir "%WINSRVDVDDIR%"
if errorlevel 1 goto E_MKDIR
mkdir "%TEMPDIR%"
if errorlevel 1 goto E_MKDIR
mkdir "%EXTRACTDIR%"
if errorlevel 1 goto E_MKDIR
mkdir "%MOUNTDIR%"
if errorlevel 1 goto E_MKDIR

echo.
echo Copy Windows Server 2008 R2 SP1 DVD to the temporary directory
echo.
echo Please insert the Windows Server 2008 R2 SP1 %WINSRVARCH% DVD into the DVD drive %DVDDRIVE%
echo.
pause
xcopy %DVDDRIVE%\*.* /E /F "%WINSRVDVDDIR%"

echo.
echo Copy language pack to %TEMPDIR%
echo.
if not exist "%WORKDIR%\%LPFILENAME%" goto E_LPFILE
copy "%WORKDIR%\%LPFILENAME%" "%TEMPDIR%"

rem Set count of available Windows Server 2008 R2 versions
if "%WINSRVARCH%"=="amd64" set VERSIONS=8

rem Add language pack files to the installation images
for /L %%i in (1, 1, %VERSIONS%) do (
  echo.
  echo Add language pack files to the installation image %%i of %VERSIONS%
  echo.
  "%KITPATH%\Tools\x86\Servicing\Dism.exe" /Mount-Wim /Wimfile:"%WINSRVDVDDIR%\sources\install.wim" /Index:%%i /MountDir:"%MOUNTDIR%"
  if errorlevel 1 goto E_MOUNT
  "%KITPATH%\Tools\x86\Servicing\Dism.exe" /Image:"%MOUNTDIR%" /Add-Package /PackagePath:"%TEMPDIR%\%LPFILENAME%"
  "%KITPATH%\Tools\x86\Servicing\Dism.exe" /Image:"%MOUNTDIR%" /Gen-LangIni /Distribution:"%WINSRVDVDDIR%"
  "%KITPATH%\Tools\x86\Servicing\Dism.exe" /Image:"%MOUNTDIR%" /Set-AllIntl:%LANGUAGE%
  "%KITPATH%\Tools\x86\Servicing\Dism.exe" /Image:"%MOUNTDIR%" /Set-TimeZone:"Central Europe Standard Time"
  "%KITPATH%\Tools\x86\Servicing\Dism.exe" /Image:"%MOUNTDIR%" /Set-SetupUILang:%LANGUAGE% /Distribution:"%WINSRVDVDDIR%"
  "%KITPATH%\Tools\x86\Servicing\Dism.exe" /Image:"%MOUNTDIR%" /Gen-LangIni /Distribution:"%WINSRVDVDDIR%"
  "%KITPATH%\Tools\x86\Servicing\Dism.exe" /Image:"%MOUNTDIR%" /Get-Packages /Format:Table
  "%KITPATH%\Tools\x86\Servicing\Dism.exe" /Image:"%MOUNTDIR%" /Get-Intl
  "%KITPATH%\Tools\x86\Servicing\Dism.exe" /Unmount-Wim /MountDir:"%MOUNTDIR%" /Commit
  if errorlevel 1 goto E_UNMOUNT
)

echo.
echo Add language pack files to the Windows Server 2008 R2 SP1 DVD
echo.
expand "%TEMPDIR%\%LPFILENAME%" -F:* "%EXTRACTDIR%"
xcopy "%EXTRACTDIR%\setup\sources\%LANGUAGE%\*" "%WINSRVDVDDIR%\sources\%LANGUAGE%" /cherkyi
xcopy "%EXTRACTDIR%\sources\license\%LANGUAGE%\*" "%WINSRVDVDDIR%\sources\license\%LANGUAGE%" /cherkyi

echo.
echo Add language pack files to the boot image
echo.
"%KITPATH%\Tools\x86\Servicing\Dism.exe" /Mount-Wim /WimFile:"%WINSRVDVDDIR%\sources\boot.wim" /Index:2 /MountDir:"%MOUNTDIR%"
if errorlevel 1 goto E_MOUNT
xcopy "%EXTRACTDIR%\setup\sources\%LANGUAGE%\*" "%MOUNTDIR%\sources\%LANGUAGE%" /cherkyi
xcopy "%EXTRACTDIR%\sources\license\%LANGUAGE%\*" "%MOUNTDIR%\sources\license\%LANGUAGE%" /cherkyi
copy "%WINSRVDVDDIR%\sources\lang.ini" "%MOUNTDIR%\sources\lang.ini"
"%KITPATH%\Tools\x86\Servicing\Dism.exe" /Unmount-Wim /MountDir:"%MOUNTDIR%" /Commit
if errorlevel 1 goto E_UNMOUNT

echo.
echo Create Windows Server 2008 R2 SP1 %WINSRVARCH% MUI ISO image
echo.
"%KITPATH%\Tools\x86\oscdimg.exe" -u1 -b"%WINSRVDVDDIR%\boot\etfsboot.com" "%WINSRVDVDDIR%" "%WINSRVDVDISO%"
if errorlevel 1 goto E_CREATEISO

echo.
echo Remove temporary directories
echo.
if exist "%WINSRVDVDDIR%" rmdir /s /q "%WINSRVDVDDIR%"
if errorlevel 1 goto E_DELDIR
if exist "%TEMPDIR%" rmdir /s /q "%TEMPDIR%"
if errorlevel 1 goto E_DELDIR

goto DONE

:E_KITPATH
set MESSAGE=Could not find the AIK/OPK directory!
goto END

:E_DELDIR
set MESSAGE=Could not delete temporary directory!
goto END

:E_MKDIR
set MESSAGE=Could not create temporary directory!
goto END

:E_LPFILE
set MESSAGE=Could not find language pack!
goto END

:E_MOUNT
set MESSAGE=Could not mount WIM image!
goto END

:E_UNMOUNT
set MESSAGE=Could not unmount WIM image!
goto END

:E_CREATEISO
set MESSAGE=Could not create "%WINSRVDVDISO%"!
goto END

:DONE
cls
set MESSAGE=Done
goto END

:END
echo.
echo %MESSAGE%
echo.
pause
exit


Dieser Eintrag wurde am 08.04.2012 erstellt und zuletzt am 20.10.2013 bearbeitet.

Direkter Link zu dieser Seite: http://www.gtkdb.de/index_14_1561.html

[ Zur Startseite ]   [ Zur Kategorie ]


Valid XHTML 1.0 Transitional Valid CSS Valid Atom 1.0

© 2004-2018 by Georg Kainzbauer